​MQL4（11）：EA布局的标准结构和运行流程

// === 1. 预处理指令区 === 
#property strict // 严格模式（强烈建议） 
#property copyright "tudaojiaoyi" 
#property link "http://www.eamql5.com" 
#property version "1.00" // EA版本号

// === 2. 外部输入参数区 (用户可调节) === 
extern double LotSize = 0.1; // 下单手数 
extern int Slippage = 3; // 最大滑点 
extern int TakeProfit = 50; // 止盈点数 
extern int StopLoss = 30; // 止损点数 
extern bool UseTrailing = true; // 是否启用移动止盈 
extern int MagicNumber = 123456; // 识别订单用的魔术编号 

// === 3. 全局变量区 (程序内部用，不对外暴露) === 
int g_Ticket = -1; // 当前订单号 
bool g_HasOpenPosition = false; // 是否已有持仓 
datetime g_LastOrderTime = 0; // 上次开单时间 

//+------------------------------------------------------------------+ 
//| 初始化函数 (EA加载时执行一次) | 
//+------------------------------------------------------------------+ 
int OnInit() 
 {
  Print("EA初始化完成: ", WindowExpertName()); 
  g_HasOpenPosition = false; 
  return(INIT_SUCCEEDED); // 返回初始化成功
 } 

//+------------------------------------------------------------------+ 
//| 去初始化函数 (EA被卸载时执行一次) | 
//+------------------------------------------------------------------+ 
void OnDeinit(const int reason)
 {
  Print("EA卸载，原因代码: ", reason);
 } 

//+------------------------------------------------------------------+ 
//| 核心执行函数 (每个新的Tick执行) | 
//+------------------------------------------------------------------+ 
void OnTick()
 {
  // 核心逻辑流程
  if(!IsNewBar())
  return;
  // 非新K线，不处理
  if(!g_HasOpenPosition)
   {
    if(CheckEntryCondition())
     {
      OpenOrder();
     }
   }
  else
   {
    ManageOpenOrders(); // 持仓管理，比如移动止盈
   }
 } 

//+------------------------------------------------------------------+ 
//| 辅助函数：检测是否形成新K线 | 
//+------------------------------------------------------------------+ 
bool IsNewBar()
 {
 static datetime lastTime = 0; 
 if (Time[0] != lastTime)
  {
   lastTime = Time[0]; 
   return true; 
  }
  return false; 
 } 

//+------------------------------------------------------------------+ 
//| 辅助函数：检查入场条件 | 
//+------------------------------------------------------------------+ 
bool CheckEntryCondition()
 { 
 // 这里填写你自己的交易信号逻辑 
 if (iRSI(NULL, 0, 14, PRICE_CLOSE, 0) < 30)
  {
  return true; // RSI低位，买入信号 
  } 
 return false; 
 } 

//+------------------------------------------------------------------+ 
//| 辅助函数：开仓函数 | 
//+------------------------------------------------------------------+ 
void OpenOrder()
 {
  double price = Ask; 
  double sl = price - StopLoss * Point; 
  double tp = price + TakeProfit * Point; 
  int ticket = OrderSend(Symbol(), OP_BUY, LotSize, price, Slippage, sl, tp, "EA Order", MagicNumber, 0, clrBlue);
  if(ticket > 0) 
   { 
    g_Ticket = ticket;
    g_HasOpenPosition = true; 
    g_LastOrderTime = TimeCurrent(); 
    Print("开仓成功，订单号: ", ticket); 
   } 
  else 
   {
 Print("开仓失败，错误代码: ", GetLastError()); 
   } 
} 

//+------------------------------------------------------------------+ 
//| 辅助函数：管理已有持仓 (如移动止盈) | 
//+------------------------------------------------------------------+ 
void ManageOpenOrders() 
 {
  for(int i=OrdersTotal()-1; i>=0; i--) 
   { 
    if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES))
    {
     if(OrderMagicNumber() == MagicNumber && OrderSymbol() == Symbol()) 
      { 
       if(UseTrailing)
       ApplyTrailingStop(); 
      } 
    } 
  } 
} 

//+------------------------------------------------------------------+ 
//| 辅助函数：应用移动止盈功能 | 
//+------------------------------------------------------------------+ 
void ApplyTrailingStop()
 {
  double trailingStop = 30; // 自定义移动止盈点数 
  double newStopLoss = Bid - trailingStop * Point; 
  if(OrderType() == OP_BUY) 
   { 
    if(newStopLoss > OrderStopLoss())
     {
      OrderModify(OrderTicket(), OrderOpenPrice(), newStopLoss, OrderTakeProfit(), 0, clrBlue); 
      Print("移动止盈更新！"); 
     } 
   } 
} 

//+------------------------------------------------------------------+